home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).zip
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).po
/
IIGS.COLOR.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
1KB
|
25 lines
10 REM PROGRAM IIGS.COLOR
20 REM SET THE COLORS OF THE IIGS SCREEN
30 REM YOU CAN SET THE BACKGROUND, BORDER
40 REM AND TEXT INDEPENDENTLY
50 REM DANGER..THE BORDER COLOR REGISTER C034..49204 IS SHARED BY THE CLOCK.
60 REM TEXT AND BACKGROUND SHARE C022..49186
70 REM COLOR RANGE IS FROM 0 TO 15
80 REM THIS ROUTINE USES BIT.BREAKER AND REASSEMBLER TO MODIFY
90 REM THE BORDER REGISTER WITHOUT CHANGING THE CLOCK
100 HOME : PRINT "COLOR RANGE FROM 0 (BLACK) TO 15 (WHITE)": PRINT
110 PRINT "IF YOU SET THE TEXT AND BACKGOUND TO THE "
120 PRINT "SAME COLOR YOU CAN'T READ THE SCREEN !": PRINT
130 PRINT "ENTER TEXT COLOR ";: INPUT TX
140 PRINT : PRINT "ENTER BACKGROUND COLOR ";: INPUT BK
150 PRINT : PRINT "ENTER BORDER COLOR ";: INPUT BD
160 REM BREAK DOWN THE NUMBER
170 FOR BT = 0 TO 7:A(BT) = (BD - INT(BD/2) *2):BD = INT(BD/2): NEXT
180 BV = PEEK(49204): REM GET BORDER REGISTER VALUE
190 FOR BT = 0 TO 7:B(BT) = (BV - INT(BV/2) *2):BV = INT(BV/2): NEXT
200 REM LOWER NIBBLE IS INPUT..UPPER NIBBLE IS CLOCK VALUE FROM 49204
210 REM REASSEMBLE THE BORDER BITS INTO DECIMAL VALUE
220 V = A(0) +2 *A(1) +4 *A(2) +8 *A(3) +16 *B(4) +32 *B(5) +64 *B(6) +128 *B(7)
230 POKE 49186,TX *16 +BK: REM SET TEXT AND BACKGROUND
240 POKE 49204,V: REM SET BORDER COLOR
250 VTAB 22: PRINT "PRESS A KEY TO CONTINUE";: GET A$: GOTO 100